#!/usr/bin/perl

# See the POD documentation at the end of this
# document for detailed copyright information.
# (c) 2002 Steffen Mueller, all rights reserved.

use strict;
use warnings;

use vars qw/$VERSION/;
$VERSION = "1.00";

use Pod::Select;

foreach my $module (@ARGV) {

   print "Versions found for $module:\n";

   if (defined $module and $module ne '') {
      eval "require $module;";
      warn($@), next if $@;
      no strict 'refs';
      my %versions = map {($_, ${"${module}::$_"})} grep /version/i, keys %{"${module}::"};
      print "$_: $versions{$_}\n" foreach keys %versions;
   }

   my $filename = join '/', (split /::|'/, $module);

   my @files = map { s/\/$//; "$_/$filename.pm" } @INC;

   @files = grep { -f $_ } @files;

   podselect({-sections => ["VERSION", "Version", "version"]}, @files);

   print "\n";

}


sub usage {
   print <<HERE;
Usage: modver modulename [modulename, ...]

Prints any version info found.
HERE
}

__END__

=pod

=head1 NAME

modver - search for Perl module version Information

=head1 VERSION

Current version is 1.00.

=head1 AUTHOR

Steffen Mueller, mail at steffen-mueller dot net

=head1 COPYRIGHT

Copyright (c) 2002 Steffen Mueller. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut